TEMPLATE = subdirs

thermalsim = $$(THERMALSIM)
isEmpty(thermalsim) {
    thermalsim = false
}

$$eval(thermalsim) {
    message(Thermal Simulation Feature Enabled)
} else {
    message(Thermal Simulation Feature Disabled)
}

dramsys_disable_coverage_check = $$(DRAMSYS_DISABLE_COVERAGE_CHECK)
isEmpty(dramsys_disable_coverage_check) {
    message(Coverage check ENABLED)
} else {
    message(Coverage check DISABLED)
}

systemc_home = $$(SYSTEMC_HOME)
isEmpty(systemc_home) {
    systemc_home = /opt/systemc
}
message(SystemC home is $${systemc_home})

SUBDIRS += library
SUBDIRS += simulator
SUBDIRS += traceAnalyzer

library.subdir = library
simulator.subdir = simulator
traceAnalyzer.subdir = traceAnalyzer

# Check if gem5 is installed:
gem5 = $$(GEM5)
isEmpty(gem5) {
    message(GEM5 environment variable not found)
    message(Gem5 Simulation Disabled)
} else {
    message(Gem5 Simulation Feature Enabled)
    message(Gem5 home is $${gem5})
    DEFINES += DRAMSYS_GEM5
    SUBDIRS += gem5
    gem5.subdir = gem5
    gem5.depends = library simulator
}

# Define Build Order
simulator.depends = library

# Additional Files:
# tests folder (DRAMSys/tests)
include(tests/tests.pri)

DISTFILES += ../README.md
